-- IDL module extracted from ITU-T Q Suppl. 28 (12/1999)

// File SPFEEUserAccess.idl

	#ifndef spfeeuseraccess_idl
	#define spfeeuseraccess_idl

	#include "SPFEECommonTypes.idl"
	#include "SPFEEAccessCommonTypes.idl"
 
	module SPFEEUserAccess {

	typedef SPFEECommonTypes::t_PropertyList t_CancelAccessSessionProperties;

	interface i_UserAccessGetInterfaces {

	// behaviour
	// behaviourText 
	// "This interface allows the provider  domain to get 
	// interfaces exported by this user domain."

	// usage
	// "This interface is not to be exported across 
	// Ret RP. It is inherited into the exported interfaces."

		void getInterfaceTypes (
			out SPFEECommonTypes::t_InterfaceTypeList itfTypes
		) raises (
			SPFEECommonTypes::e_ListError
		);

		void getInterface (
			in SPFEECommonTypes::t_InterfaceTypeName itfType,
			in SPFEECommonTypes::t_MatchProperties desiredProperties,
			out SPFEECommonTypes::t_InterfaceStruct itf
		) raises (
			SPFEECommonTypes::e_InterfacesError,
			SPFEECommonTypes::e_PropertyError
		);


		void getInterfaces (
			out SPFEECommonTypes::t_InterfaceList itfs
		) raises (
			SPFEECommonTypes::e_ListError
		); 

	}; // i_UserAccessGetInterfaces

	interface i_UserAccess 
		: i_UserAccessGetInterfaces
	{
	// behaviour
	// behaviourText 
	// "This interface is provided to a UA to perform actions during an 
	// access session. It inherits from i_UserAccessGetInterfaces to 
	// allow the retailer to ask for other interfaces exported by the 
	// consumer domain. (The retailer cannot register his own // // /
	// interfaces!)";
		// usage
		// " ";


	// DRAFT: this operation is draft only, any feedback on this operation is
	//			most welcome.
			void cancelAccessSession(
				in t_CancelAccessSessionProperties options
		);

	}; // i_UserAccess

	interface i_UserInvite
	{
	// behaviour
	// 	behaviourText 
	// 	"This interface is provided to a UA, to invite the user to:
	//		- join a service session
	//		- request an access session
	//	";
	//	usage
	//	 " ";

	// inviteUser() types

		void inviteUser (
			in  SPFEEAccessCommonTypes::t_SessionInvitation invitation,
			out SPFEECommonTypes::t_InvitationReply reply
			)
		raises (SPFEEAccessCommonTypes::e_InvitationError)
		;

		void cancelInviteUser (
			in SPFEECommonTypes::t_UserId inviteeId,
			in SPFEEAccessCommonTypes::t_InvitationId id
		) raises (
			SPFEEAccessCommonTypes::e_InvitationError
		);

	}; // i_UserInvite


	interface i_UserTerminal {


	// behaviour
	// behaviourText 
	// "This interface is provided to a UA, to gain information about the 
	// terminal context.";
		// usage
		// " ";

	// getTerminalInfo() types


		void getTerminalInfo(
			out SPFEEAccessCommonTypes::t_TerminalInfo terminalInfo
		);
	}; // i_UserTerminal

	interface i_UserAccessSessionInfo
	{
	// ...AccessSessionInfo() types

	oneway void newAccessSessionInfo (
			in SPFEEAccessCommonTypes::t_AccessSessionInfo accessSession
		);

	oneway void endAccessSessionInfo (
			in SPFEEAccessCommonTypes::t_AccessSessionId asId
		);

	oneway void cancelAccessSessionInfo (
			in SPFEEAccessCommonTypes::t_AccessSessionId asId
		);

	oneway void newSubscribedServicesInfo (
			in SPFEEAccessCommonTypes::t_ServiceList services
		);

	};	// i_UserAccessSessionInfo

	interface i_UserSessionInfo
	{
	oneway void newSessionInfo (
			in SPFEEAccessCommonTypes::t_SessionInfo session
		);

	oneway void endSessionInfo (
			in SPFEECommonTypes::t_SessionId sessionId
		);

	oneway void endMyParticipationInfo (
			in SPFEECommonTypes::t_SessionId sessionId
		);

	oneway void suspendSessionInfo (
			in SPFEECommonTypes::t_SessionId sessionId
		);

	oneway void suspendMyParticipationInfo (
			in SPFEECommonTypes::t_SessionId sessionId
		);

	oneway void resumeSessionInfo (
			in SPFEEAccessCommonTypes::t_SessionInfo session
		);


	oneway void resumeMyParticipationInfo (
			in SPFEEAccessCommonTypes::t_SessionInfo session
		);

	oneway void joinSessionInfo (
			in SPFEEAccessCommonTypes::t_SessionInfo session
		);

	}; // i_UserSessionInfo

	};

	#endif